Gradle多項目構建
Gradle可以輕鬆處理各種大小規模的項目。小項目由一個單一的構建文件和一個源代碼樹構成。 大項目可以將其拆分成更小的，相互依賴的模塊，以便更容易理解。Gradle完美支持這種多項目構建的場景。
多項目構建的結構
這種構建有各種形狀和大小，但它們都有一些共同的特點 -
- 在項目的根目錄或主目錄中都有一個
settings.gradle文件。 - 根目錄或主目錄都有一個
build.gradle文件。 - 具有自己的
*.gradle構建文件的子目錄（某些多項目構建可能會省略子項目構建腳本）。
要列出構建文件中的所有項目，可以使用以下命令。
D:/water>gradle -q projects如果命令執行成功，將獲得以下輸出。
D:/water>gradle -q projects
------------------------------------------------------------
Root project
------------------------------------------------------------
Root project 'water'
+--- Project ':bluewhale'
/--- Project ':krill'
To see a list of the tasks of a project, run gradle <project-path>:tasks
For example, try running gradle :bluewhale:tasks報告將顯示每個項目的描述（如果指定）。可以使用以下命令指定描述。 將其粘貼到build.gradle文件中。
description = 'The shared API for the application'指定常規構建配置
在根項目中的build.gradle文件中，常規配置可以應用於所有項目或僅應用於子項目。
allprojects {
group = 'com.example.gradle'
version = '0.1.0'
}
subprojects {
apply plugin: 'java'
apply plugin: 'eclipse'
}這指定了一個公共com.example.gradle組和一個0.1.0版本到所有項目。subprojects 閉合所有應用對子項目通用配置，但不對根項目應用，如：allprojects閉合。
項目指定配置和依賴關係
核心ui和util子項目也可以有自己的build.gradle文件，如果它們有特定的需求，那麼一般不會應用根項目配置。
例如，ui項目通常具有對核心項目的依賴性。所以在ui項目中需要有配置自己的build.gradle文件來指定這個依賴。
dependencies {
compile project(':core')
compile 'log4j:log4j:1.2.17'
}項目依賴項可使用項目方法指定。
Gradle多項目構建的示例
定義公共行爲
讓我們看看下面的一個例子的項目樹。這是一個多項目構建，其中包含一個名爲water的根項目和一個名稱爲bluewham的子項目。在這個示例中，我們把在創建一個目錄D:/water，作爲根項目的目錄。
多項目樹 - water 和bluewham項目的構建佈局如下圖所示 -
water/
build.gradle
settings.gradle
bluewhale/首先，創建一個文件 settings.gradle 並寫入以下代碼內容 -
include 'bluewhale'bluewhale項目的構建腳本在哪裏？ 在Gradle中構建腳本是可選的。顯然，對於單個項目構建，如果沒有構建腳本那麼項目是沒有意義的。但對於多項目構建情況不同。讓我們看看water項目的構建腳本並執行它，創建一個文件build.gradle 並寫入以下代碼：
Closure cl = { task -> println "I'm $task.project.name" }
task hello << cl
project(':bluewhale') {
task hello << cl
}並執行 gradle -q hello 輸出結果如下 -
D:/water>gradle -q hello
I'm water
I'm bluewhaleGradle允許從構建腳本中訪問多項目構建的任何項目。 Project API提供了一個名稱爲project（）的方法，它將一個路徑作爲參數，並返回此路徑的Project對象。
爲每個項目顯式添加任務是不方便的。我們可以稍微做一下調整，先將另一個名稱爲krill的項目添加到多項目構建中。
現在目錄結構看起來如下所示 -
water/
build.gradle
settings.gradle
bluewhale/
krill/再次編輯 settings.gradle 將以下代碼加入到文件中 -
include 'bluewhale', 'krill'現在我們已經重寫 water 構建腳本並將其放在一行中。
將文件water項目中的 build.gradle 並寫入以下代碼：
allprojects {
task hello << { task -> println "I'm $task.project.name" }
}並執行 gradle -q hello 輸出結果如下 -
D:/water>gradle -q hello
I'm water
I'm bluewhale
I'm krill這是如何工作的？ Project API提供了一個屬性allprojects，它返回當前項目及其下面所有子項目的列表。 如果使用閉包調用allprojects，則閉包的語句將委派給與所有項目相關聯的項目。當然也可以通過allprojects.each進行迭代，但這將更冗長。
其他構建系統使用繼承作爲定義公共行爲的主要方法。Gradle也爲項目提供繼承，您將在後面看到。但Gradle使用配置注入作爲定義公共行爲的常用方式。這是一種非常強大和靈活的配置多項目構建的方式。共享配置的另一種可能性是使用公共外部腳本。
子項目配置
Project API還提供了一個僅用於訪問子項目的屬性。
定義公共行爲
定義所有項目和子項目的公共行爲，編輯 build.gradle 文件使用以下代碼 -
allprojects {
task hello << {task -> println "I'm $task.project.name" }
}
subprojects {
hello << {println "- I depend on water"}
}並執行 gradle -q hello 輸出結果如下 -
D:/water>gradle -q hello
I'm water
I'm bluewhale
- I depend on water
I'm krill
- I depend on water注意兩個代碼片段引用「hello」任務。 第一個，它使用「task」關鍵字，構建任務並提供它的基本配置。第二部分不使用「task」關鍵字，因爲它進一步配置現有的「hello」任務。只能在項目中構建一次任務，但可以添加任意數量的代碼塊以提供其他配置。
添加指定行爲
可以在常見行爲之上添加指定的行爲。要應用這個特定的行爲，通常將項目特定的行爲放在項目的構建腳本中。我們可以爲 bluewhale 項目添加項目特定的行爲，如下所示：
編輯 build.gradle 文件使用以下代碼 -
allprojects {
task hello << {task -> println "I'm $task.project.name" }
}
subprojects {
hello << {println "- I depend on water"}
}
project(':bluewhale').hello << {
println "- I'm the largest animal that has ever lived on this planet."
}並執行 gradle -q hello 輸出結果如下 -
D:/water>gradle -q hello
I'm water
I'm bluewhale
- I depend on water
- I'm the largest animal that has ever lived on this planet.
I'm krill
- I depend on water正如上面所說的，通常把項目特定的行爲放入這個項目的構建腳本中。現在重構代碼並向krill項目添加一些項目特定的行爲。
定義 krill 項目的具體行爲
構建佈局如下圖中所示 -
water/
build.gradle
settings.gradle
bluewhale/
build.gradle
krill/
build.gradlesettings.gradle 文件的內容 -
include 'bluewhale', 'krill'bluewhale/build.gradle 文件的內容 -
hello.doLast {
println "- I'm the largest animal that has ever lived on this planet."
}krill/build.gradle 文件的內容 -
hello.doLast {
println "- The weight of my species in summer is twice as heavy as all human beings."
}build.gradle 文件的內容 -
allprojects {
task hello << {task -> println "I'm $task.project.name" }
}
subprojects {
hello << {println "- I depend on water"}
}並執行 gradle -q hello 輸出結果如下 -
D:/water>gradle -q hello
I'm water
I'm bluewhale
- I depend on water
- I'm the largest animal that has ever lived on this planet.
I'm krill
- I depend on water
- The weight of my species in summer is twice as heavy as all human beings.